0 REM  GOTO 6740: 07/30/88 @ 06:20:C64 EXIT @ 610/6180
10 REM -------------------------
20 REM ! AUTHORS: DAVE HAMMOND !
30 REM !   AND    * JIM BORDEN !
40 REM ! *BY UPTIME MAGAZINE   !
50 REM -------------------------
60 :
70 GOTO 460:-SKIP SUBS!
80 REM--EDIT LABEL SUBS--
90 FORX=0TO4:AA$(X)=Z$:NEXT:REM--FILL W/BLANKS
100 XR=0:YC=0:CF=0:REM ROW=0 / COL=0 /CHANGE FLAG =>1=CURSOR/2=TEXT CHANGE
110 REM--MAIN LABEL INPUT LOOP--
120 FOR QQ=0TO2:QQ=.
130 IF OC$(XR,YC)=""THENOC$(XR,YC)=" "
140 PRINT"[146]"OC$(XR,YC)"[157]";
150 GET A$:IF A$="" GOTO 150
160 K=ASC(A$)AND127:IF K=13 GOTO 250:REM CR
170 IFK=17 GOTO270:REM--UP/DOWN
180 IFK=20 GOTO320:REM--DEL/INST
190 IFK=29 GOTO380:REM--RT/LF
200 IFA$="[133]" GOTO430:REM--F1 KEY
210 IFK<32 THEN NEXT:QQ:--NOT VALID!
220 IF A$=CHR$(34)THEN NEXT:REM--NO QUOTES ALLOWED
230 CF=CF OR 2:PRINT""A$;:OC$(XR,YC)=A$:YC=YC+1:IFYC>29THENYC=YC-1:PRINT"[157]";
240 NEXT:QQ
250 PRINT""OC$(XR,YC):XR=XR+1:YC=0:PRINTTAB(5):IF XR>4THENXR=0:PRINT"[145][145][145][145][145]";
260 NEXT:QQ
270 IFA$="[145]"GOTO300:REM--CUR UP
280 PRINT""OC$(XR,YC)"[157]";:XR=XR+1:IFXR=5THENXR=0:PRINT"[145][145][145][145][145]";
290 NEXT:QQ
300 PRINT""OC$(XR,YC)"[157][145]";:XR=XR-1:IF XR<0THEN XR=4:PRINT"";
310 NEXT:QQ
320 CF=CF OR 1:IF A$<>"[148]" GOTO 350:REM--DEL KEY!
330 PRINT""OC$(XR,YC)"[157]";:FOR X=28TOYC STEP-1:OC$(XR,X+1)=OC$(XR,X):NEXT:OC$(XR,YC)=" ":PRINTA$" [157][145]"
340 PRINTTAB(36)CHR$(20)"[145]":PRINTTAB(YC+5);:NEXT:QQ
350 IF YC=0THEN NEXT:REM--IGNORE DEL
360 YC=YC-1:FOR X=YCTO28:OC$(XR,X)=OC$(XR,X+1):NEXT:OC$(XR,X)=" ":PRINTA$"[145]"
370 PRINTTAB(34)CHR$(148)"[157][157] [145]":PRINTTAB(YC+5);:NEXT:QQ
380 CF=CF OR 1:IFA$="[157]"GOTO410 :REM--CUR LEFT
390 PRINT""OC$(XR,YC);:YC=YC+1:IFYC>29THENYC=29:PRINT"[157]";
400 NEXT:QQ
410 PRINT""OC$(XR,YC)"[157][157]";:YC=YC-1:IFYC<0THENYC=0:PRINT"";
420 NEXT:QQ
430 QQ=9:NEXT:PRINT"[147][215]ORKING":FORQQ=0TO4:AA$(QQ)="":FOR X=0TO29:AA$(QQ)=AA$(QQ)+OC$(QQ,X):NEXT:NEXT:HP=0:X=FRE(1):RETURN:-TO MENU
440 :
450 REM -- START-UP SEQUENCE --
460 PRINT"[147]"CHR$(8)CHR$(142):REM--BLANK SCREEN & UPPERCASE
470 POKE53280,0:POKE53281,0:REM--BLACK ON LT. GREY
480 GOSUB 6180:REM--INITIALIZE VARIABLES
490 GOSUB 5890:REM--DISPLAY COVER SCREEN
495 POKE 198,0
500 GET A$:IF A$<>CHR$(13) THEN 500:REM--DELAY LOOP
510 PRINT"[147]"CHR$(14);:REM--LOWERCASE
520 :
530 REM--MAIN MENU--
540 GOSUB 1010:REM--DISPLAY MENU
550 GOSUB 1270:REM--GET KEYPRESS
560 MM=0
570 ON KEY GOSUB 650, 740,830,920,1900
580 REM   FILE,LABEL,LPTR,INFO,EXIT
590 :
600 IF XT AND CM=128 THEN POKE828,173:PRINT"[147][152]";:END:--RESTORE F'(null)S/FULL SCREEN
610 IF XT THEN SYS UPTIME:REM--IF EXIT FLAG THEN EXIT
620 GOTO 540:REM--MAIN MENU ON NO EXIT
630 :
640 REM--FILE MGMNT MENU--
650 M=KEY:EC=3:AT$="[146][158]"
660 GOSUB 1010:REM--DISPLAY MENU
670 GOSUB 1270:REM--GET KEYPRESS
680 ON KEY GOSUB 1950,1950,   1950,  1950,2710,1900
690 REM     LOAD,SAVE,SCRATCH,RENAME, DIR,EXIT
700 IF (MM) THEN RETURN
710 GOTO 660
720 :
730 REM--LABEL MGMNT MENU--
740 M=KEY
750 GOSUB 1010:REM--DISPLAY MENU
760 GOSUB 1270:REM--GET KEYPRESS
770 ON KEY GOSUB 3690,  3770,  3860,4070,4210,1900
780 REM    ADD,CHANGE,DELETE,LIST,SORT,EXIT
790 IF (MM) THEN RETURN
800 GOTO 750
810 :
820 REM--PRINTER MENU--
830 M=KEY
840 GOSUB 1010:REM--DISPLAY MENU
850 GOSUB 1270:REM--GET KEYPRESS
860 ON KEY GOSUB 4720,4900,4930,1900
870 REM   BLOCK, ONE, ALL,EXIT
880 KEY=M:IF (MM) THEN RETURN
890 GOTO 830
900 :
910 REM--INFO & HELP MENU--
920 M=KEY
930 GOSUB 1010:REM--DISPLAY MENU
940 GOSUB 1270:REM--GET KEYPRESS
950 ON KEY GOSUB 6810,7050,1900
960 REM    INFO,HELP,EXIT
970 IF (MM) THEN RETURN
980 GOTO 920
990 :
1000 REM--DISPLAY MENU--
1010 IF HP=0 THEN HP=1:GOSUB 1170:REM--PRINT HEADER
1020 GOSUB 1220:REM--PRINT CURSOR LEGEND
1030 GOSUB 1100:REM--CLEAR TEXT AREA
1040 PRINT"[158]";SPC(SP(M));HD$(M);""
1050 FOR MN=1 TO M(M)
1060 PRINTSPC(9)"";MN;"[157]. [158]";M$(M,MN);""
1070 NEXT:RETURN
1080 :
1090 REM--CLEAR TEXT AREA--
1100 PRINT"";
1110 FOR C1=1 TO CN
1120 PRINT"                                       "
1130 NEXT
1140 CN=17:RETURN
1150 :
1160 REM--PRINT HEADER--
1170 PRINT"[147]"SPC(9)"[159][176][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][174]"
1180 PRINT "[192][192][192][192][192][192][192][192][192][179] [204]ABEL [205]AGIC 64/128 [171][192][192][192][192][192][192][192][192][192]";
1190 PRINTSPC(9)"[173][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][189]":RETURN
1200 :
1210 REM--PRINT CURSOR LEGEND--
1220 XR=21:YC=5:P=0:GOSUB 1510
1230 PRINT"[159][213]SE [195]URSOR [213]P/[196]OWN[159] FOR [195]HOICE"
1240 PRINTSPC(8)"  [213]SE [210][197][212][213][210][206][159] TO [211]ELECT  ":RETURN
1250 :
1260 REM--MAKE SELECTION--
1270 XR=7:YC=8:GOSUB 1510:REM--POSITION CURSOR
1280 :
1290 KEY=1:MR=7+2*(M(M)-1):PRINT"[150][186][157]";
1300 GET K$:IF K$<>""GOTO 1300
1310 GET K$:IF K$=""GOTO 1310
1320 IF K$=CHR$(13)GOTO 1480
1330 IF K$=CHR$(145)GOTO 1410
1340 IF K$<>CHR$(17)GOTO 1310
1350 :
1360 REM--CURSOR DOWN--
1370 XR=XR+2:KEY=KEY+1:IF KEY>M(M)THEN KEY=1: XR=7
1380 GOTO 1440
1390 :
1400 REM--CURSOR UP--
1410 XR=XR-2:KEY=KEY-1:IF KEY=0 THEN KEY=M(M):XR=MR
1420 :
1430 REM--PRINT CURSOR--
1440 PRINT" ":GOSUB 1510:REM--POS CUR
1450 PRINT"[150][186][157]";:GOTO 1310
1460 :
1470 REM--SELECTION MADE/EXIT
1480 RETURN
1490 :
1500 REM--CUR POS SUB--
1510 PRINTLEFT$("",XR+1);TAB(YC);
1520 RETURN :[FOR ANY COMMO(null)RE!]
1530 :
1540 REM--KBD INPUT SUB--
1550 CT=0:T$="":CS$="[164][157]":PRINTAT$CS$;
1560 GET K$:IF K$<>""GOTO 1560
1570 GET K$:IF K$=""GOTO 1570
1580 IF K$="?" OR K$="*"GOTO1570:REM--NO WILDCARDS! (SAVE, ETC.)
1590 IF K$=CHR$(13)GOTO 1860
1600 IF K$<>CHR$(20)GOTO 1690
1610 :
1620 REM--DELETE A CHARACTER--
1630 IF CT=0 GOTO 1570
1640 IF (M<>2)OR(CT<>MAX) THEN PRINT"[155] [157]";
1650 PRINT"[157] [157]";CS$;
1660 CT=CT-1:T$=LEFT$(T$,CT):GOTO 1570
1670 :
1680 REM--TRAP KEYS--
1690 IF CT=MAX GOTO 1570
1700 IF M<>2 THEN 1760:REM--NOT DOING LABELS
1710 :
1720 IF(K$>CHR$(132))AND(K$<CHR$(141))GOTO 1860
1730 IF(K$=CHR$(17))OR(K$=CHR$(145))GOTO 1860
1740 IF(K$=CHR$(19))OR(K$=CHR$(147))THEN 1860
1750 :
1760 IF M<>2 AND K$=CHR$(46)GOTO 1570
1770 IF K$=CHR$(34)GOTO 1570
1780 IF K$<CHR$(32)GOTO 1570
1790 IF (K$>CHR$(95))AND(K$<CHR$(193))GOTO 1570
1800 IF K$>CHR$(218)GOTO 1570
1810 :
1820 CT=CT+1:T$=T$+K$:PRINTAT$;K$;
1830 IF CT<>MAX THEN PRINTCS$;
1840 GOTO 1570
1850 :
1860 IF (CT<>MAX)OR(M<>2) THEN PRINTAT$" "
1870 RETURN
1880 :
1890 REM--PREPARE TO EXIT--
1900 XT=1
1910 IF M<>0 THEN XT=0:M=0:MM=1
1920 RETURN
1930 :
1940 REM--GET FILENAME--
1950 CN=20:GOSUB 1100:REM--CLEAR TEXT AREA
1960 PRINT"";
1970 SP=INT((40-LEN(M$(M,KEY)))/2)
1980 PRINTSPC(SP)"[158]"M$(M,KEY)""
1990 IF KEY=2 AND LF$<>"" THEN PRINT"[195]URRENT [198]ILENAME: "LF$"[157][157][157][157]    "
2000 :
2010 FOR X=1 TO 2
2020 PRINT"[158]"PR$(X);
2030 PRINT"[163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163]"
2040 PRINTSPC(26)"[145][145]";
2050 MAX=12:GOSUB 1550:REM--KBD INPUT
2060 IF T$=""THEN X=2:NEXT:RETURN
2070 F$(X)=T$+".LBL"
2080 IF (KEY<>4) THEN X=2
2090 NEXT
2100 :
2110 ON KEY GOSUB 2160,2350,   2520,  2610
2120 REM   LOAD,SAVE,SCRATCH,RENAME
2130 RETURN
2140 :
2150 REM--LOAD A LABEL FILE--
2160 OPEN15,8,15,"I0"
2170 GOSUB 5850:REM--ERR CK
2180 IF EN<>0 THEN CLOSE15:GOSUB 5580:RETURN
2190 :
2200 FL$=F$(1):OPEN8,8,8,FL$
2210 GOSUB 5850:REM--ERR CK
2220 IF EN<>0 THEN CLOSE8:CLOSE15:FL$="":GOSUB 5580:RETURN
2230 :
2240 INPUT#8,MX
2250 FOR X=0TOMX:FORY=0TO4:REM--5 LINES(Y),MX RECORDS(X)
2260 INPUT#8,L$(X,Y):NEXT:NEXT:REM--READ RECORDS
2270 MX=MX+1:IF MX=20 GOTO2290
2280 FOR X=XTO19:FOR Y=0TO4:L$(X,Y)="":NEXT:NEXT:REM--CLEAR LABELS
2290 CLOSE8:GOSUB 5850:REM--ERR CK
2300 CLOSE15:MM=1:IF EN<>0 THEN FL$="":MM=0:GOSUB 5580
2310 IF MM THEN M=0:LF$=FL$:REM--TO MAIN AFTER LOAD
2320 RETURN
2330 :
2340 REM --SAVE A LABEL FILE--
2350 OPEN15,8,15,"I0"
2360 GOSUB 5850:REM--ERR CK
2370 IF EN<>0 THEN CLOSE15:GOSUB 5580:RETURN
2380 :
2390 IF MX<1 THEN PRINT"[206]O [210]ECORDS!":FORX=0TO999:NEXT:CLOSE15:RETURN
2400 FL$=F$(1):OPEN8,8,8,FL$:GOSUB5850:CLOSE8:REM--ERR MSG
2410 IF EN=0THEN PRINT#15,"S0:"+FL$:REM SCRATCH OLD VERSION
2420 :
2430 OPEN8,8,8,FL$+",S,W":PRINT#8,MX-1:Q$=CHR$(34)
2440 FOR X=0TOMX-1:FORY=0TO4
2450 PRINT#8,Q$L$(X,Y)Q$:REM--QUOTES FOR COMMA, ETC.
2460 NEXT:NEXT:CLOSE8:GOSUB 5850
2470 CLOSE15:MM=1:IF EN THEN MM=0:GOSUB 5580
2480 IF MM THEN M=0:REM--TO MAIN
2490 RETURN
2500 :
2510 REM--SCRATCH A FILE--
2520 OPEN15,8,15,"I0"
2530 GOSUB 5850:REM--ERR CK
2540 IF EN<>0 THEN CLOSE 15:GOSUB 5580:RETURN
2550 :
2560 PRINT#15,"S0:"+F$(1)
2570 GOSUB5850:CLOSE15:EM$=EM$+"="+STR$(ET):GOSUB 5580:RETURN
2580 REM--NUMBER OF SCRATCHED FILES
2590 :
2600 REM--RENAME A FILE--
2610 OPEN15,8,15,"I0"
2620 GOSUB 5850:REM--ERR CK
2630 IF EN<>0 THEN CLOSE 15:GOSUB 5580:RETURN
2640 :
2650 PRINT#15,"R0:"+F$(2)+"=0:"+F$(1)
2660 GOSUB 5850:REM--ERR CK
2670 CLOSE 15:IF EN<>0 THEN GOSUB 5580
2680 RETURN
2690 :
2700 REM--GET DIRECTORY--
2710 CN=20:GOSUB 1100:REM--CLEAR TEXT AREA
2720 PRINT"";
2730 SP=INT((40-LEN(M$(M,KEY)))/2)
2740 PRINTSPC(SP)"[158]"M$(M,KEY)""
2750 PRINT"[145][158] [196]ISK:": PRINT" [204]ABEL [198]ILES:[145][145][145]"
2760 :
2770 OPEN 15,8,15,"I0"
2780 GOSUB 5850:REM--ERR CK
2790 IF EN<>0 THEN CLOSE15:GOSUB 5580:RETURN
2800 :
2810 OPEN2,8,2,"#"
2820 T=18:S=0:BP=144:DN$=""
2830 GOSUB 5810:REM--BLOCK READ
2840 GOSUB 5850:REM--ERR CK
2850 IF EN<>0 THEN CLOSE 2:CLOSE 15:GOSUB 5580:RETURN
2860 GOSUB 5820:REM--BUFFER POINTER
2870 GOSUB 3470: DN$=T$:REM--GET DISK NAME
2880 SP=INT((40-(LEN(DN$)+3))/2)
2890 PRINTSPC(SP)"[150]";DN$;"..."
2900 S=1:BP=0:CT=0:DD=0
2910 GOSUB 3230:REM--CLEAR DIR. AREA
2920 REM---START OF SECTOR READING IN SEARCH OF LABEL FILE---
2930 GOSUB 3580: REM--READ A SECTOR
2940 IF EN<>0 THEN RETURN
2950 :
2960 FOR DE=1 TO 8:REM--8 FILENAMES PER SECTOR
2970 GOSUB 5820:REM--BUFFER POINTER
2980 GET#2,FT$:IF FT$="" THEN FT$=CHR$(0)
2990 BP=BP+3:IF ASC(FT$)=129 THEN GOSUB 3320:REM--GET DIR ENTRY
3000 BP=BP+29
3010 IF(T=0)AND(BP>=S)THEN DE=8:DD=1:REM--DIR END
3020 IF CT=20 THEN DE=8:REM--MAX OF 20 FILES
3030 NEXT
3040 :
3050 IF DD=0 THEN 2930:REM--READ ANOTHER SECTOR
3060 IF (CT=0) THEN PRINT"[158][206]O [204]ABEL [198]ILES"
3070 CLOSE2:CLOSE15
3080 :
3090 XR=21:YC=7:GOSUB 1510
3100 PRINT"[159][208]RESS  KEY[159] TO [204][207][193][196] FILE OR"
3110 XR=23:YC=8:GOSUB 1510
3120 PRINT"[159][208]RESS [158][210][197][212][213][210][206][159] TO [195]ONTINUE"
3130 GET K$:IF K$=""GOTO 3130
3140 IF K$=CHR$(13)THEN RETURN
3150 DE=-1:IF K$=>"A"AND K$<="T"THEN DE=ASC(K$)-65
3160 IF DE<0 OR DE=>CT GOTO3130:REM--NO VALID KEY
3170 XR=21:YC=0:GOSUB1510:PRINTZ$"        ":PRINT"     "Z$
3180 XR=21:YC=0:GOSUB1510:PRINTZ$:PRINT"[145]     [204][207][193][196][201][206][199]: "FA$(DE)"[157][157][157].. "
3190 F$(1)=FA$(DE):OPEN15,8,15:GOTO2200:REM--TO LOAD ROUTINE...
3200 REM--IF LOAD IS SELECTED,RETURN FROM LOAD SUB--
3210 :
3220 REM--CLEAR DIRECTORY AREA--
3230 XR=10:YC=0:GOSUB 1510:REM--POS CUR
3240 FOR X=0 TO 9:PRINT" ";
3250 PRINT" "CHR$(X+65);".               ";
3260 PRINT" "CHR$(X+75);".               "
3270 NEXT
3280 PRINTSPC(15)"[215]ORKING..."
3290 XR=10:YC=5:GOSUB 1510:REM--PLACE CURSOR
3300 :
3310 REM--GET DIRECTORY ENTRY--
3320 GOSUB5820:REM--BUFFER POINTER
3330 GOSUB3470:REM--READ DIR ENTRY
3340 FL$=T$:IF RIGHT$(FL$,4)=".LBL" THEN GOSUB3380:REM--PRINT F'NAME
3350 FL$="":RETURN
3360 :
3370 REM--PRINT FILENAME--
3380 FL$=LEFT$(FL$,LEN(FL$)-4)
3390 FA$(CT)=T$:REM--SAVE NAME FOR DIR.LOAD
3400 PRINT"[158]"FL$
3410 CT=CT+1:XR=XR+1
3420 IF XR=21 THEN XR=11:YC=24
3430 GOSUB 1510:REM--PLACE CURSOR
3440 RETURN
3450 :
3460 REM--READ DIRECTORY ENTRY--
3470 T$="":FOR T1=1 TO 16
3480 GET#2,BY$:IF BY$=""THEN BY$=CHR$(0)
3490 IF BY$=CHR$(160)GOTO 3540
3500 IF BY$<CHR$(32)THEN BY$="?"
3510 IF(BY$>CHR$(95))AND(BY$<CHR$(193))THEN BY$="?"
3520 IF BY$>CHR$(218)THEN BY$="?"
3530 T$=T$+BY$
3540 NEXT
3550 RETURN
3560 :
3570 REM--READ SECTOR+T&S POINTERS--
3580 GOSUB 5810:REM--BLOCK READ
3590 GOSUB 5850:REM--ERR CK
3600 IF EN<>0 THEN CLOSE2:CLOSE15:GOSUB 5580:RETURN
3610 :
3620 BP=0:GOSUB 5820:REM--BUF PTR
3630 GET#2,T$:IF T$=""THEN T$=CHR$(0)
3640 GET#2,S$:IF S$=""THEN S$=CHR$(0)
3650 T=ASC(T$):S=ASC(S$):BP=2:NE=1
3660 RETURN
3670 :
3680 REM--ADD LABEL--
3690 IF MX>19THENPRINTTAB(13)"[198]ILE IS [198]ULL!":FORX=0TO999:NEXT:RETURN
3700 RN=MX:GOSUB4960:REM--INIT LABEL SCREEN
3710 FORXR=0TO4:FORYC=0TO29:OC$(XR,YC)=" ":NEXT:NEXT:GOSUB90:REM--INPUT LABEL
3720 IF CF<2 GOTO3740:REM--NO TEXT CHANGE=NOT NEW!
3730 FOR X=0TO4:L$(MX,X)=AA$(X):NEXT:MX=MX+1:REM--RECORD NEW LABEL/INC MAX
3740 RETURN
3750 :
3760 REM--CHANGE A LABEL--
3770 IFMX=0 THEN PRINT""TAB(13);:GOTO2390:REM---NONE
3780 GOSUB 5310:GOSUB 5020:REM--GET #/-DISPLAY LABELS
3790 FORXR=0TO4:AA$(XR)=L$(RN,XR):FORYC=0TO29:OC$(XR,YC)=MID$(L$(RN,XR),YC+1,1)
3800 NEXT:NEXT
3810 GOSUB100:REM--INPUT LABEL
3820 IF CF THEN FOR X=0TO4:L$(RN,X)=AA$(X):NEXT:REM--CHANGE LABEL
3830 RETURN
3840 :
3850 REM--DELETE A LABEL--
3860 IF MX=0 GOTO 3770:REM--NO LABELS!
3870 GOSUB 5310:PRINT:REM--GET LABEL #
3880 IF T$="!" THEN XR=11:R=0:GOTO 3870:--TRY AGAIN
3890 PRINT"[147]"LB$(0):RC$="#"+RIGHT$(STR$(101+RN),2):PRINT" "RC$LB$(1)
3900 FOR X=2 TO 7:PRINT LB$(X):NEXT:PRINT LB$(0)""
3910 FOR X=0 TO 4:PRINTTAB(5)""L$(RN,X):NEXT
3920 PRINTTAB(10)"[193]RE YOU SURE? (Y/N)"
3930 GET A$:IF A$=""THEN3930
3940 IF A$<>"Y" AND A$<>"N"GOTO 3930
3950 PRINT"[147]":HP=0:REM--CLEAR SCREEN,NEED HEADER
3960 IF A$="N" THEN RETURN:REM--ABORT!
3970 :
3980 PRINT""TAB(15)"[215]ORKING..."
3990 REM--DELETE THE LABEL
4000 FOR X=RN TO MX-1:REM--'PULL LABELS DOWN'
4010 FOR Y=0 TO 4:L$(X,Y)=L$(X+1,Y):NEXT
4020 NEXT:MX=MX-1:REM --ONE,1 LESS
4030 PRINT"[147]":RN=FRE(1):REM FORCE COLLECTION
4040 RETURN
4050 :
4060 REM--LIST LABELS--
4070 RN=0:GOSUB 4960:SF=1:REM--LIST FIRST 3 LABELS
4080 XR=24:YC=0:GOSUB1510:REM--CURSOR ON LAST LINE
4090 PRINT" [211]CROLL WITH CURSOR UP/DOWN--[198]1 TO [197]XIT[145]"
4100 GET A$:IF A$="" GOTO 4100:REM--WAIT FOR KEY
4110 IF A$="" AND RN<MX-3 GOTO 4150:REM--DOWN
4120 IF A$="[145]" AND RN>0 GOTO 4170:REM--UP
4130 IF A$="[133]" THEN PRINT"[147]":HP=0:SF=0:RETURN
4140 GOTO 4100:REM--NO VALID KEY
4150 REM--SCROLL DOWN--
4160 RN=RN+1:GOSUB 4960:GOTO4080
4170 REM--SCROLL UP--
4180 RN=RN-1:GOSUB 4960:GOTO4080
4190 :
4200 REM--SORT LABELS--
4210 PRINT"[147]"TAB(5)"[194]Y WHICH FIELD? [163][157][145]";:SF=0
4220 GET A$:IFA$=""THEN4220
4230 IF A$=CHR$(13) AND SF>0 GOTO4270
4240 IF A$>"0" AND A$<"6" THEN SF=VAL(A$):PRINTA$"[157]";
4250 GOTO4220
4260 :
4270 IF MX<2 GOTO 4370:REM--NO RECORDS TO SORT!
4280 PRINT"[147]";TAB(15);"[215]ORKING...":SF=SF-1
4290 FOR X=0TO MX-2:XR=X:REM--FIND 'LOWEST STRING'
4300 :FOR Y=X TO MX-1
4310 : IF L$(XR,SF)>L$(Y,SF) THEN XR=Y
4320 : NEXT:IF XR=X GOTO 4360:REM--NO SWAP
4330 : FOR Y=0TO4:T$=L$(X,Y)
4340 :  L$(X,Y)=L$(XR,Y):L$(XR,Y)=T$
4350 : NEXT
4360 NEXT:PRINT"[145]"TAB(15);"[195]OMPLETE...":X=FRE(1)
4370 PRINT"[147]":HP=0:SF=0:RETURN
4380 :
4390 REM--GET 2 DIGITS SUB--
4400 PRINTTAB(10)"[152][176][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][174][146]  "
4410 PRINTTAB(10)"[221]             : [146]0  [221][146]  "
4420 PRINTTAB(10)"[173][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][189][146]  "
4430 PRINTTAB(24-LEN(T$))"[145][145]"T$"";:CT=0:AA$(0)="0":AA$(1)=" "
4440 :
4450 GET A$:IF A$="" GOTO 4450
4460 IF A$=CHR$(13)THEN RN=VAL(AA$(0)+AA$(1)):PRINTAA$(CT):RETURN
4470 IF A$="[157]"AND CT=1 THEN PRINTAA$(1)"[157][157]";:CT=0
4480 IF A$=""AND CT=0 THEN PRINTAA$(0);:CT=1
4490 IF A$=>"0" AND A$<="9" THENAA$(CT)=A$:CT=CT+1:PRINTA$;
4500 IF A$=" " THEN AA$(CT)=A$:PRINTA$;:CT=CT+1
4510 IF CT>1 THEN CT=1:PRINT"[157]";
4520 PRINT"[146]"AA$(CT)"[157]";:GOTO 4450
4530 :
4540 REM--OPEN PRINTER--
4550 OPEN4,4,7:CLOSE4:EC=ST
4560 IF EC<>0 THEN EC=2:GOSUB 5580:RETURN:REM--PRINTER ERR
4570 OPEN4,4,7:CMD4,"";:REM--ALL OUTPUT TO PRINTER
4580 REM --- CUSTOMIZE YOUR PRINTER HERE ---
4590 :
4600 :
4610 :
4620 RETURN
4630 :
4640 REM--PRINT LABEL 'X'--
4650 FOR XR=1 TO RN:REM--PRINT 'RN' COPIES
4660 :FOR Y=0 TO 4:IF LEFT$(L$(X,Y),1)="_" THEN PRINT#4:GOTO4680
4670 :PRINT#4,L$(X,Y)
4680 :NEXT:PRINT#4:GET A$:IFA$<>""THENXR=RN:X=YC:REM--ABORT
4690 NEXT:RETURN
4700 :
4710 REM--PRINT BLOCK OF LABELS--
4720 T$="[198]IRST [204]ABEL #":GOSUB4380:XR=RN-1
4730 IF XR<0OR XR>MX-1 THEN PRINT"[145][145][145][145]";:GOTO4720
4740 :
4750 T$="[204]AST [204]ABEL #"
4760 GOSUB4380:YC=RN-1:IF XR<0 AND YC<MX THEN XR=YC:REM--ADJ FOR ONE IF NEEDED
4770 IF (YC<0 OR YC>MX-1)OR(YC<XR) THEN PRINT"[145][145][145][145]";:GOTO4760
4780 :
4790 T$="[206]O. OF [195]OPIES":GOSUB 4380
4800 IF RN<1 THEN PRINT"[145][145][145][145]";:GOTO4790
4810 :
4820 GOSUB 4550:REM--OPEN PRINTER
4830 IF EC>0 THEN RETURN:REM--PRINTER NOT READY
4840 FORX=0TO9:GETA$:NEXT:FOR X=XR TO YC
4850 :GOSUB 4650:REM--PRINT LABEL 'X'
4860 NEXT:CLOSE4
4870 RETURN
4880 :
4890 REM--PRINT SINGLE LABEL--
4900 T$="[215]HICH [204]ABEL":XR=-1:GOTO 4760
4910 :
4920 REM--PRINT ALL LABELS--
4930 XR=0:YC=MX-1:GOTO 4790
4940 :
4950 REM--INIT LABEL SCREEN--
4960 IF SF=0 THEN PRINT"[147]"
4970 PRINT"";LB$(0):IF RN=0THENLS=0:LP=0
4980 IF RN=1THENLS=0:LP=1:REM--LABEL START/PRINT POS.
4990 IF RN>1 AND SF=0 THENLS=MX-2:LP=2:REM--ADD A LABEL
5000 IF RN>0 AND SF>0 THENLS=RN:LP=0:REM--LIST A LABEL
5010 GOTO 5050:REM--SKIP CHANGE CODE
5020 PRINT"[147][146]";LB$(0):IF RN=0THEN LS=0:LP=0:GOTO5050
5030 IF RN=MX-1 AND MX>2 THEN LS=MX-3:LP=MX-2
5040 LS=RN-1:LP=1
5050 FOR I=1 TO 3
5060 RC$="#"+RIGHT$(STR$(100+LS+I),2)
5070 IF SF THEN PRINT" "RC$"[155]";:IFI<3THENPRINT:GOTO5150
5080 IF SF GOTO 5150
5090 REM---NO BLANKS FOR 'LIST'^
5100 FOR J=1TO8
5110 IF J=1 THEN PRINT" ";RC$;
5120 IF (I<>3) OR (J<>8) THEN PRINTLB$(J)
5130 IF (I=3) AND (J=8) THEN PRINTLB$(0);
5140 : NEXT
5150 NEXT
5160 PRINT"";:FOR I=LS TO LS+2:IF I>19 GOTO 5190
5170 FOR J=0 TO 4
5180 PRINTTAB(5)""L$(I,J):NEXT:IF I<LS+2THEN PRINT"";
5190 :NEXT
5200 PRINT""TAB(5);:IF LP>0THENFORX=1TOLP:PRINT"";:NEXT:REM--POS CUR
5210 RETURN
5220 :
5230 REM--GOTO RECORD #--
5240 !GOSUB 5310: REM--GOTO WHERE?
5250 !GOSUB 4960: REM--PRINT LABEL SCREEN
5260 :
5270 :!:XR=2: YC=5: R=1: GOSUB 1510
5280 !K=7: RETURN
5290 :
5300 REM--GOTO WHERE?--
5310 XR=XR-(R-1)+1: YC=10: GOSUB 1510
5320 PRINT"[176][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][174]"
5330 PRINTSPC(10)"[221] [204]ABEL NUMBER:    [221]"
5340 PRINTSPC(10)"[173][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][189]"
5350 YC=25: XR=XR+1: GOSUB 1510
5360 GOSUB 5430: REM--GET--NUMERIC KBD
5370 RN=VAL(T$)-1
5380 IF RN<0 THEN RN=0:T$="!"
5390 IF RN=>MX THEN RN=MX-1:T$="!"
5400 RETURN
5410 :
5420 REM--NUMERIC KBD INPUT--
5430 T$="": CT=0
5440 GET K$: IF K$="" THEN 5440
5450 IF K$=CHR$(13) THEN 5560
5460 IF K$<>CHR$(20) THEN 5520
5470 :
5480 IF CT=0 THEN 5440
5490 PRINT"[157] [157]";
5500 CT=CT-1:T$=LEFT$(T$,CT):GOTO 5440
5510 :
5520 IF CT=2 THEN 5440
5530 IF (K$<CHR$(48))OR(K$>CHR$(57))THEN 5440
5540 CT=CT+1:T$=T$+K$:PRINT""K$;:GOTO 5440
5550 :
5560 RETURN
5570 REM--ERROR HANDLING--
5580 XR=10:YC=0:GOSUB 1510
5590 PRINTSPC(4)"[176][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][174]"
5600 FOR I=1 TO 6
5610 PRINTSPC(4)"[221]                              [221]"
5620 NEXT
5630 PRINTSPC(4)"[173][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][189]"
5640 XR=12: GOSUB 1510
5650 IF EC=3 AND EN=1 THEN5680
5660 SP=INT(((40-LEN(EM$(EC)))/2))
5670 PRINTSPC(SP)""EM$(EC)
5680 IF EC=3 THEN GOSUB 5750
5690 XR=15: YC=8: GOSUB 1510
5700 PRINT"[208]RESS [210][197][212][213][210][206] TO [195]ONTINUE"
5710 GET K$: IF K$<>CHR$(13) THEN 5710
5720 RETURN
5730 :
5740 REM--DISK ERR MSG--
5750 XR=13:GOSUB 1510
5760 SP=INT(((40-LEN(EM$))/2))
5770 PRINTSPC(SP)""EM$
5780 RETURN
5790 :
5800 REM--DISK DIRECT-ACCESS--
5810 PRINT#15,"U1";2;0;T;S: RETURN
5820 PRINT#15,"B-P";2;BP: RETURN
5830 :
5840 REM--CLEAR DISK ERR CH--
5850 INPUT#15,EN,EM$,ET,ES
5860 RETURN
5870 :
5880 REM--DISPLAY COVER SCREEN--
5890 PRINT"[147][155]";
5900 PRINT" --------------------------------------"
5910 PRINT"    [213][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][201]   "
5920 PRINT"  [209] [221]              BY              [221] [209] "
5930 PRINT"    [221]                              [221]   "
5940 PRINT"    [221]   DAVE HAMMOND               [221]   "
5950 PRINT"    [221]            AND JIM BORDEN    [221]   "
5960 PRINT"  [209] [221]                              [221] [209] "
5970 PRINT"    [202][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][203]   "
5980 PRINT"                                       "
5990 PRINT"    [213][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][201]   "
6000 PRINT"  [209] [221]                              [155][221] [209] "
6010 PRINT"    [221]        [146][169][169]     [146][169] [223][169]           [155][221]   "
6020 PRINT"    [221]       [146][169][169]     [146][169][169][146][169][169][146][169][169]          [155][221]   "
6030 PRINT"    [221]      [146][169][169]ABEL [146][169][169][146][169][169][146][169][169]AGIC       [155][221]   "
6040 PRINT"  [209] [221]      [184][184][184][184][184][184] [184] [184] [184][184][184][184][184][184]       [155][221] [209] "
6050 PRINT"    [202][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][203]   "
6060 PRINT"                                       "
6070 PRINT"    [213][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][201]   "
6080 PRINT"  [209] [221]                              [221] [209] "
6090 PRINT"    [221]         PUBLISHED BY         [221]   "
6100 PRINT"    [221]     SOFTDISK PUBLISHING      [221]   "
6110 PRINT"    [221]                              [221]   "
6120 PRINT"  [209] [221]   PRESS RETURN TO CONTINUE   [221] [209] "
6130 PRINT"    [202][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][203]   "
6140 PRINT" --------------------------------------[145]"
6150 RETURN
6160 :
6170 REM--PROGRAM INITIALIZATION--
6180 UPTIME=(8*4096)+4
6190 XR=.:YC=.:QQ=.:XT=.:M=.:HP=.:MM=1:CN=17:RC=.:MX=.
6200 DIM OC$(4,29),AA$(4),L$(20,4), M$(4,6),M(5),SP(5),HD$(5),PR$(2),F$(2)
6210 DIM FA$(19)
6220 FL$="":LF$="":Z$="                              ":REM 30 CHAR 'BLANK'
6230 :
6240 PR$(1)="[197]NTER CURRENT FILENAME: 0:[157][157][157]"
6250 PR$(2)="[197]NTER NEW FILENAME:     0:[157][157][157]"
6260 :
6270 EM$(0)="  "
6280 EM$(1)="[206]O [195]URRENT [198]ILENAME"
6290 EM$(2)="[208]RINTER [206]OT [210]EADY"
6300 EM$(3)="[196]ISK [193]CCESS [197]RROR"
6310 :
6320 LB$(0)=" [155]--------------------------------------"
6330 LB$(1)="[155][176][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][174]   "
6340 LB$(2)=" [155] O [221]                              [221] O "
6350 LB$(3)=" [155]   [221]                              [221]   "
6360 LB$(4)=" [155]   [221]                              [221]   "
6370 LB$(5)=" [155]   [221]                              [221]   "
6380 LB$(6)=" [155] O [221]                              [221] O "
6390 LB$(7)=" [155]   [173][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][189]   "
6400 LB$(8)=" [155]                                      "
6410 :
6420 FOR A=0 TO 4
6430 READ HD$(A),SP(A),M(A)
6440 :
6450 FOR B=1 TO M(A)
6460 READ M$(A,B)
6470 NEXT:NEXT
6480 :
6490 IF FRE(0)=FRE(1) GOTO 6520:REM--C-64
6500 CM=128:(null)15:PRINT"[147]":IF (null)(X)=5THEN (null) 20,0,59,24:(null)6,1
6510 M$(0,5)="[197]XIT TO [194]ASIC 7.0":POKE 828,183:REM-- 128 F'KEYS=64 F'KEYS
6520 RETURN
6530 :
6540 REM--PROGRAM DATA--
6550 DATA "[204]ABEL [205]AGIC [205]ENU", 12, 5
6560 DATA "[198]ILE [205]ANAGEMENT", "[204]ABEL [205]ANAGEMENT", "[208]RINTER [207]PERATIONS"
6570 DATA "[201]NFO & [200]ELP", "[197]XIT TO [213]P[212]IME"
6580 :
6590 DATA "[198]ILE [205]ANAGEMENT", 12, 6
6600 DATA "[204]OAD A [204]ABEL [198]ILE", "[211]AVE A [204]ABEL [198]ILE", "[211]CRATCH A [198]ILE"
6610 DATA "[210]ENAME A [198]ILE", "[204]ABEL [198]ILE [196]IRECTORY", "[210]ETURN TO [205]AIN [205]ENU"
6620 :
6630 DATA "[204]ABEL [205]ANAGEMENT", 12, 6
6640 DATA "[193]DD A [204]ABEL", "[195]HANGE A [204]ABEL", "[196]ELETE A [204]ABEL", "[204]IST THE [204]ABELS"
6650 DATA "[211]ORT THE [204]ABELS", "[210]ETURN TO [205]AIN [205]ENU"
6660 :
6670 DATA "[208]RINTER [207]PERATIONS", 11, 4
6680 DATA "[208]RINT [194]LOCK OF [204]ABELS", "[208]RINT [207]NE [204]ABEL", "[208]RINT [193]LL [204]ABELS"
6690 DATA "[210]ETURN TO [205]AIN [205]ENU"
6700 :
6710 DATA "[201]NFO & [200]ELP", 14, 3
6720 DATA "[201]NFORMATION", "[200]ELP", "[210]ETURN TO [205]AIN [205]ENU"
6730 :
6800 REM--INFO & HELP--
6810 CN=20:GOSUB 1100
6820 PRINT"";
6830 PRINTSPC(14)"[158][201]NFO & [200]ELP"
6840 :
6850 PRINT"    [204]ABEL [205]AKER 64/128 IS A LABEL GEN-"
6860 PRINT" ERATING PROGRAM FOR MAKING ALMOST ANY"
6870 PRINT" TYPE OF LABEL FOR ANY NEED.  [212]HE PRO-"
6880 PRINT" GRAM SUPPORTS STANDARD, SINGLE COLUMN,"
6890 PRINT" 3 1/2";CHR$(22);" X 1";CHR$(22);" LABELS.  [201]T WILL ALLOW YOU"
6900 PRINT" TO PRINT 1 LABEL, MULTIPLE PRINTINGS"
6910 PRINT" OF ONE LABEL, A GROUP OF LABELS, A"
6920 PRINT" USER'S SELECTION OF LABELS, OR ALMOST"
6930 PRINT" ANY COMBINATION OF THE ABOVE."
6940 PRINT:PRINT"    [212]HE PROGRAM HAS FOUR DISTINCT"
6950 PRINT" SECTIONS: [198]ILE [205]ANAGEMENT, [204]ABEL [205]AN-"
6960 PRINT" AGEMENT, [208]RINTER [207]PERATIONS, AND [200]ELP."
6970 PRINT" [197]ACH SECTION IS MENU DRIVEN AND EASILY"
6980 PRINT" OPERATED.  [212]HERE ARE AMPLE OPPORTUNI-"
6990 PRINT" TIES FOR RETURNING TO PREVIOUS MENUS"
7000 PRINT" OR EXITING.[158][157]([211]PACEBAR TO [197]XIT)";
7010 GET A$:IFA$<>" " GOTO7010
7020 PRINT"[147]";:GOSUB1170:KEY=4:RETURN
7030 :
7040 REM--INFO--
7050 GOSUB 7250:REM--CLEAR TEXT/POS CURSOR
7060 PRINT"";
7070 PRINTTAB(10)"[158][200][197][204][208] [212]OPICS ARE:":PRINT
7080 PRINT" A  [204]OAD A [198]ILE      H  [196]ELETE A [204]ABEL":PRINT
7090 PRINT" B  [211]AVE A [198]ILE      I  [204]IST [204]ABELS":PRINT
7100 PRINT" C  [211]CRATCH [198]ILE     J  [211]ORT [204]ABELS":PRINT
7110 PRINT" D  [210]ENAME [198]ILE ":PRINT
7120 PRINT" E  [198]ILE [196]IRECTORY   K  [208]RINT [194]LOCK":PRINT
7130 PRINT"                     L  [208]RINT [207]NE":PRINT
7140 PRINT" F  [193]DD A [204]ABEL      M  [208]RINT [193]LL":PRINT
7150 PRINT" G  [195]HANGE A [204]ABEL":PRINT""
7160 PRINT"[158]  [211]ELECT BY [204]ETTER[158]  OR  [213]SE [198]1 TO [197]XIT"
7170 GET A$:IF A$="" GOTO7170
7180 IF A$="[133]"THEN GOSUB1170:KEY=4:RETURN:REM--EXIT FROM HERE...
7190 IF A$<"A" OR A$>"M" GOTO 7170
7200 X=ASC(A$)-64:ON X GOSUB 7270,7350,7440,7500,7540,7640,7880,7940,8000,8110,8220,8340,8440
7210 GOTO7050:--MORE (null)
7220 :
7230 XR=23:YC=0:GOSUB1510:RETURN:REM--POS CURSOR
7240 :
7250 CN=20:GOSUB1100:PRINT"";:RETURN:REM--POS BELOW HEADER
7260 :
7270 GOSUB 7250
7280 PRINT"  [204]OAD A [198]ILE--[152][197]NTER THE FILENAME AT":PRINT
7290 PRINT"  THE PROMPT AND HIT RETURN[146].":PRINT
7300 PRINT"    [193]LSO SEE THE '[196]IRECTORY' COMMAND."
7310 GOSUB 7230:PRINTTAB(12)"[159][211]PACEBAR TO [197]XIT";
7320 GET A$:IF A$<>" "THEN7320
7330 RETURN
7340 :
7350 GOSUB 7250
7360 PRINT"  [211]AVE A FILE--[152][197]NTER THE FILENAME AT":PRINT
7370 PRINT"  THE PROMPT AND HIT RETURN[146].":PRINT
7380 PRINT"    [212]HE CURRENT FILENAME IS SHOWN SO":PRINT
7390 PRINT"  YOU CAN ENTER IT FOR AN UPDATE.":PRINT
7400 PRINT"  [212]HIS IS A [211][193][198][197] SAVE AND REPLACE.":PRINT
7410 PRINT"  [196]O [206][207][212] USE '@0:'!":PRINT
7420 GOTO7310:--(null)
7430 :
7440 GOSUB 7250
7450 PRINT"  [211]CRATCH A [198]ILE--[152][211]AME AS [196][207][211] SCRATCH":PRINT
7460 PRINT"  COMMAND, BUT CAN ONLY WORK ON LABEL":PRINT
7470 PRINT"  FILES."
7480 GOTO7310:--(null)
7490 :
7500 GOSUB 7250
7510 PRINT"  [210]ENAME A [198]ILE--[152][211]AME AS [196][207][211] SCRATCH":PRINT
7520 GOTO7460
7530 :
7540 GOSUB 7250
7550 PRINT"  [198]ILE [196]IRECTORY--[152][212]HIS COMMAND WILL":PRINT
7560 PRINT"  READ AND PRINT UP TO 20 FILENAMES ON":PRINT
7570 PRINT"  THE SCREEN.  [212]O LOAD ONE OF THESE":PRINT
7580 PRINT"  FILES, JUST PRESS THE KEY FOR THE":PRINT
7590 PRINT"  FILE YOU WANT TO LOAD.":PRINT
7600 PRINT"    [201]F THERE ARE A LOT OF FILES ON THE":PRINT
7610 PRINT"  DISK, THIS COMMAND MAY BE SLOW.":PRINT
7620 GOTO7310:--(null)
7630 :
7640 GOSUB 7250
7650 PRINT"  [193]DD A [204]ABEL--[152][213]SE THIS COMMAND TO ADD":PRINT
7660 PRINT"  LABELS TO YOUR FILE.  [201]NPUT IS THROUGH"
7670 PRINT"  A [199][197][212] ROUTINE.  [198]OR THIS REASON, THE":PRINT
7680 PRINT"  [201][206][211][146] AND [196][197][204][146] KEYS ARE SLUGGISH.":PRINT
7690 PRINT"    [212]HE [198]1[146] KEY WILL EXIT TO THE MENU.":PRINT
7700 PRINT"    [210][197][212][213][210][206][146] WILL MOVE THE CURSOR TO THE":PRINT
7710 PRINT"  NEXT LINE FOR MORE INPUT.":PRINT
7720 PRINT"    [205]OST KEYS ARE ALLOWED INCLUDING THE":PRINT
7730 PRINT"  COMMA AND COLON.":GOSUB7230
7740 PRINTTAB(10)"[200]IT ANY KEY FOR MORE.[146]";
7750 GET A$:IF A$=""GOTO 7750
7760 :
7770 GOSUB 7250
7780 PRINT"    [213]SING A _ CHARACTER IN THE FIRST":PRINT
7790 PRINT"  COLUMN WILL ALLOW A SPECIAL SORT.":PRINT
7800 PRINT"  [211]UCH LINES PRINT AS A BLANK LINE.":PRINT
7810 PRINT"    [198]OR EXAMPLE, IF YOU WANT TO SORT":PRINT
7820 PRINT"  BY ZIP CODE THEN LAST NAME, USE:":PRINT
7830 PRINT"  _92299[202]ONES  [OR]":PRINT"  _10015[211]MITH  [ETC.]":PRINT
7840 PRINT"  AND SORT BY THAT LINE.":PRINT
7850 PRINT"  [206][207][212][197]:[146] [205]AXIMUM NUMBER OF LABELS PER":PRINT
7860 PRINT"  FILE IS 20[146].":GOTO 7310:--(null)
7870 :
7880 GOSUB 7250
7890 PRINT"  [195]HANGE A [204]ABEL--[152][193]LLOWS CORRECTIONS OR":PRINT
7900 PRINT"  CHANGES TO EXISTING LABELS.  [211]AME":PRINT
7910 PRINT"  INPUT SUB AS USED BY [193]DD A [204]ABEL.":PRINT
7920 GOTO 7310:--(null)
7930 :
7940 GOSUB 7250
7950 PRINT"  [196]ELETE A [204]ABEL--[152][217]OU WILL BE ASKED":PRINT
7960 PRINT"  '[193]RE [217]OU [211]URE' BEFORE THE LABEL IS":PRINT
7970 PRINT"  DELETED.  [207]THER LABELS MOVE DOWN.":PRINT
7980 GOTO 7310:--(null)
7990 :
8000 GOSUB 7250
8010 PRINT"  [204]IST THE [204]ABELS--[152][194]EFORE SELECTING":PRINT
8020 PRINT"  OTHER COMMANDS, IT IS HELPFUL TO":PRINT
8030 PRINT"  LOOK THROUGH YOUR LABELS.  [212]HE LIST":PRINT
8040 PRINT"  COMMAND ALLOWS YOU TO SCROLL THE":PRINT
8050 PRINT"  LABELS UP OR DOWN USING THE CURSOR":PRINT
8060 PRINT"  KEYS.  [193]FTER EXAMINING YOUR LABELS,":PRINT
8070 PRINT"  USE THE [198]1[146] KEY TO RETURN TO THE":PRINT
8080 PRINT"  [204]ABEL [205]ANAGEMENT MENU."
8090 GOTO 7310:--(null)
8100 :
8110 GOSUB 7250
8120 PRINT"  [211]ORT THE [204]ABELS--[152][212]HIS COMMAND ALLOWS":PRINT
8130 PRINT"  THE LABELS TO BE SORTED BY ANY OF":PRINT
8140 PRINT"  THE 5 LINES.  [211]ELECT THE LINE AT THE":PRINT:PRINT"  PROMPT.":PRINT
8150 PRINT"    [212]HE SORT COMMAND WILL BE MOST USE-":PRINT
8160 PRINT"  FUL IF YOU SET UP A SORT LINE (WHICH":PRINT
8170 PRINT"  BEGINS WITH A _ CHARACTER).  [204]OAD AND":PRINT
8180 PRINT"  LIST THE LABEL FILE NAMED 'DEMO' TO":PRINT
8190 PRINT"  SEE HOW SORT IS USED.":PRINT
8200 GOTO 7310:--(null)
8210 :
8220 GOSUB 7250
8230 PRINT"  [208]RINT A [194]LOCK OF [204]ABELS--[152][193]FTER A":PRINT
8240 PRINT"  SORT, YOU MIGHT WANT TO MAKE LABELS":PRINT
8250 PRINT"  FOR A GROUP OF PEOPLE.  [213]SE 'LIST' TO":PRINT
8260 PRINT"  FIND THE FIRST AND LAST LABEL NUMBERS":PRINT
8270 PRINT"  YOU WANT.  [212]HEN USE THIS COMMAND TO":PRINT
8280 PRINT"  ENTER THE NUMBERS AT THE PROPER":PRINT
8290 PRINT"  PROMPT.  [193]FTER THE LABELS PRINT, YOU":PRINT
8300 PRINT"  WILL BE RETURNED TO THE PRINT MENU.":PRINT
8310 PRINT"    [211]EE OTHER [208]RINT HELP SCREENS ALSO."
8320 GOTO 7310:--(null)
8330 :
8340 GOSUB 7250
8350 PRINT"  [208]RINT [207]NE [204]ABEL--[152][211]ELECT THE LABEL":PRINT
8360 PRINT"  YOU WANT AND THE NUMBER OF COPIES.":PRINT
8370 PRINT"  [193] LABEL CAN BE PRINTED FROM 1 TO 99":PRINT
8380 PRINT"  TIMES WITH THIS COMMAND.  [200]ITTING ANY":PRINT
8390 PRINT"  KEY DURING PRINTING WILL ABORT THE":PRINT
8400 PRINT"  PRINTING AT THE END OF THE CURRENT":PRINT
8410 PRINT"  LABEL AND RETURN YOU TO THE MENU.":PRINT
8420 GOTO 8310:--(null)
8430 :
8440 GOSUB 7250
8450 PRINT"  [208]RINT [193]LL [204]ABELS--[152][212]HE ONLY PROMPT":PRINT
8460 PRINT"  WILL BE FOR THE NUMBER OF COPIES.":PRINT
8470 GOTO 8310:--(null)